mod_dg_driver Module Reference

module SCALE-DG (a main routine of regional/global model) More...

Functions/Subroutines
subroutine, public	dg_driver (comm_world, cnf_fname, path, add_path)

Detailed Description

module SCALE-DG (a main routine of regional/global model)

Description

SCALE: Scalable Computing by Advanced Library and Environment SCALE-DG: Regional / global model with atmospheric dynamical core based on DGM

Author

Yuta Kawai, Team SCALE

Function/Subroutine Documentation

dg_driver()

subroutine, public mod_dg_driver::dg_driver	(	integer, intent(in)	comm_world,
		character(len=*), intent(in)	cnf_fname,
		character(len=*), intent(in)	path,
		logical, intent(in)	add_path )

Definition at line 68 of file mod_dg_driver.F90.

 
    use scale_time_manager, only: &
      time_manager_checkstate, time_manager_advance,          &
      time_nowdate, time_nowsubsec, time_nowstep, time_nstep, &
      time_doresume, time_doend
 
    implicit none
 
    integer,          intent(in) :: comm_world
    character(len=*), intent(in) :: cnf_fname
    character(len=*), intent(in) :: path
    logical,          intent(in) :: add_path
 
    integer :: myrank
    integer :: fpm_counter
    logical :: ismaster
    logical :: sign_exit
    !---------------------------------------------------------------------------
 
    !########## Initial setup ##########
 
    ! setup standard I/O
    if ( add_path .and. path /= "" ) then
      call io_setup( modelname, trim(path)//cnf_fname, prefix=path )
    else
      call io_setup( modelname, trim(path)//cnf_fname )
    end if
 
    ! setup MPI
    call prc_local_setup( comm_world, & ! [IN]
                          myrank,     & ! [OUT]
                          ismaster    ) ! [OUT]
 
    ! setup Log
    call io_log_setup( myrank, ismaster )
 
    call initialize
 
    !###########################################################################
 
    !########## main ##########
 
#ifdef FIPP
    call fipp_start
#endif
 
    log_newline
    log_progress(*) 'START TIMESTEP'
    call prof_setprefx('MAIN')
    call prof_rapstart('Main_Loop', 0)
 
    do
 
      !*******************************************
 
      ! report current time
      call time_manager_checkstate
 
      if (time_doresume) then
        ! set state from restart file
        call restart_read
        ! history & monitor file output 
        call file_monitor_meshfield_write('MAIN', time_nowstep)
        call file_history_meshfield_write
      end if   
      
      !* Advance time *********************************
 
      call time_manager_advance
      call file_history_set_nowdate( time_nowdate, time_nowsubsec, time_nowstep )
      
      !* change to next state *************************
 
      !- USER
      call user_%update_pre( atmos )
 
      !- ATMOS
      if ( atmos%IsActivated() .and. atmos%time_manager%do_step ) then
       call atmos%update()
      end if
 
      !- USER
      call user_%update( atmos )
 
      !* restart and monitor output *******************
      if ( atmos%IsActivated() ) call atmos%vars%Monitor()
      call restart_write
      call file_monitor_meshfield_write('MAIN', time_nowstep)
 
 
      !* setup surface condition
      if ( atmos%IsActivated() ) call atmos%set_surface()
 
      !* calc tendencies and diagnostices *************
 
      !- ATMOS 
      if ( atmos%IsActivated() .and. atmos%time_manager%do_step ) then
        call atmos%calc_tendency( force=.false. )
      end if
 
      !- USER
      call user_%calc_tendency( atmos )
  
      !* output history files *************************
 
      if ( atmos%IsActivated() ) call atmos%vars%History()
      if ( atmos%phy_tb_proc%IsActivated() ) call atmos%phy_tb_proc%vars%History()
      if ( atmos%phy_mp_proc%IsActivated() ) call atmos%phy_mp_proc%vars%History()
      if ( atmos%phy_sfc_proc%IsActivated() ) call atmos%phy_sfc_proc%vars%History()
 
 
      call file_history_meshfield_write
      
      !*******************************************
      if (time_doend) exit
      
      if( io_l ) call flush(io_fid_log)
    end do
 
    call prof_rapend('Main_Loop', 0)
 
    log_progress(*) 'END TIMESTEP'
    log_newline
 
#ifdef FIPP
    call fipp_stop
#endif
 
    !########## Finalize ##########
    call finalize
 
    return

References scale_file_history_meshfield::file_history_meshfield_finalize(), scale_file_history_meshfield::file_history_meshfield_write(), scale_file_restart_meshfield::file_restart_meshfield_setup(), scale_meshfield_statistics::meshfield_statistics_setup(), scale_file_restart_meshfield::restart_file, scale_time_manager::time_doend, scale_time_manager::time_doresume, scale_time_manager::time_manager_advance(), scale_time_manager::time_manager_checkstate(), scale_time_manager::time_manager_final(), scale_time_manager::time_manager_init(), and scale_time_manager::time_manager_report_timeintervals().

Referenced by mod_dg_launcher::launcher().