scale_file_history_meshfield.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module scale_file_history_meshfield
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
 
  use scale_file_history, only: &
    file_history_setup, &
    file_history_set_nowdate, &
    file_history_truncate_1d, &
    file_history_truncate_2d, &
    file_history_truncate_3d, &
    file_history_put,         &
    file_history_write,       &
    file_history_set_dim,     &
    file_history_set_axis,    &
    file_history_finalize
 
  use scale_element_base, only: elementbase1d, elementbase2d, elementbase3d
  use scale_mesh_base1d, only: meshbase1d
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: meshbase3d
  use scale_mesh_rectdom2d, only: meshrectdom2d
  use scale_mesh_cubedom3d, only: meshcubedom3d
  use scale_mesh_cubedspheredom2d, only: meshcubedspheredom2d
  use scale_mesh_cubedspheredom3d, only: meshcubedspheredom3d
  use scale_localmesh_1d, only: localmesh1d
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
 
  use scale_meshfield_base, only: &
    meshfieldbase,                        &
    meshfield1d, meshfield2d, meshfield3d    
 
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedures
  !
  public :: file_history_meshfield_setup
  public :: file_history_meshfield_put
  public :: file_history_meshfield_in
  public :: file_history_meshfield_write  
  public :: file_history_meshfield_finalize
 
  interface file_history_meshfield_put
    module procedure file_history_meshfield_put1d
    module procedure file_history_meshfield_put2d
    module procedure file_history_meshfield_put3d
  end interface
  
  interface file_history_meshfield_in
    module procedure file_history_meshfield_in1d
    module procedure file_history_meshfield_in2d
    module procedure file_history_meshfield_in3d
  end interface
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures
  !
  private :: history_in_regvar
  private :: set_dim_axis1d
  private :: set_dim_axis2d
  private :: set_dim_axis3d
  private :: set_dim_axis2d_cubedsphere
  private :: set_dim_axis3d_cubedsphere
 
  !-----------------------------------------------------------------------------
  !
  !++ Private variables
  !
  !-------------------
  integer,          parameter :: nzs = 1
  character(len=8), parameter :: zs(nzs) = (/  "model   " /)
 
  integer  :: FILE_HISTORY_MESHFIELD_STARTDATE(6)
  real(DP) :: FILE_HISTORY_MESHFIELD_STARTSUBSEC
 
  class(MeshBase1D), pointer :: mesh1D
  class(MeshRectDom2D), pointer :: mesh2D
  class(MeshCubeDom3D), pointer :: mesh3D
  class(MeshCubedSphereDom2D), pointer :: meshCubedSphere2D
  class(MeshCubedSphereDom3D), pointer :: meshCubedSphere3D
 
  integer :: dims1D_size(1)
  integer :: dims2D_size(2)
  integer :: dims3D_size(3,nzs)
 
  logical, private :: FILE_HISTORY_FILEMESHFILED_DISABLE = .true.
 
contains
 
!----------------
 
!OCL SERIAL
  subroutine file_history_meshfield_setup( &
    mesh1D_, mesh2D_, mesh3D_,             &
    meshcubedsphere2D_, meshcubedsphere3D_ )
 
    use scale_file_h, only: &
      file_hshort
    use scale_prc, only: &
      prc_masterrank, &
      prc_myrank,     &
      prc_abort
    use scale_time, only: &
      time_nowdate,       &
      time_nowsubsec,     &
      time_startdaysec,   &
      time_dtsec,         &
      time_nowstep
    use scale_calendar, only: &
      calendar_get_name
    implicit none
 
    class(meshbase1d), intent(in), target, optional :: mesh1d_
    class(meshrectdom2d), intent(in), target, optional :: mesh2d_
    class(meshcubedom3d), intent(in), target, optional :: mesh3d_
    class(meshcubedspheredom2d), intent(in), target, optional :: meshcubedsphere2d_
    class(meshcubedspheredom3d), intent(in), target, optional :: meshcubedsphere3d_
 
    character(len=H_MID) :: file_history_meshfiled_h_title = 'SCALE-FEM FILE_HISTORY_MESHFIELD'
    character(len=H_MID) :: file_history_meshfield_t_since
 
    
    character(len=FILE_HSHORT) :: calendar
    real(dp) :: start_daysec
    !---------------------------------------------------------------------------
 
    file_history_meshfield_startdate(:) = time_nowdate
    file_history_meshfield_startsubsec  = time_nowsubsec
 
    start_daysec = time_startdaysec
    if ( time_nowdate(1) > 0 ) then
      write(file_history_meshfield_t_since,'(I4.4,5(A1,I2.2))') time_nowdate(1), &
                                                          '-', time_nowdate(2), &
                                                          '-', time_nowdate(3), &
                                                          ' ', time_nowdate(4), &
                                                          ':', time_nowdate(5), &
                                                          ':', time_nowdate(6)
      start_daysec = time_nowsubsec
    else
      file_history_meshfield_t_since = ''
    endif
 
    ! get calendar name
    call calendar_get_name( calendar )
 
    call file_history_setup( file_history_meshfiled_h_title,        & ! [IN]
      h_source, h_institute,                                        & ! [IN]
      start_daysec, time_dtsec,                                     & ! [IN]
      time_since = file_history_meshfield_t_since,                  & ! [IN]
      calendar = calendar,                                          & ! [IN]
      default_zcoord = 'model',                                     & ! [IN]
      myrank = prc_myrank                        )                    ! [IN]
 
    call file_history_set_nowdate( time_nowdate, time_nowsubsec, time_nowstep )
 
    !- Set a pointer to the  variable of mesh 
    
    nullify( mesh1d, mesh2d, mesh3d )
    nullify( meshcubedsphere2d, meshcubedsphere3d )
 
    if ( present(mesh1d_) ) then
      mesh1d => mesh1d_
      call set_dim_axis1d()
    else if ( present(mesh2d_) ) then
      mesh2d => mesh2d_
      call set_dim_axis2d()
    else if ( present(mesh3d_) ) then
      mesh3d => mesh3d_
      mesh2d => mesh3d%mesh2D
      call set_dim_axis3d()
    else if ( present(meshcubedsphere2d_) ) then
      meshcubedsphere2d => meshcubedsphere2d_
      call set_dim_axis2d_cubedsphere()
    else if ( present(meshcubedsphere3d_) ) then
      meshcubedsphere3d => meshcubedsphere3d_
      meshcubedsphere2d => meshcubedsphere3d%mesh2D
      call set_dim_axis3d_cubedsphere()
    else
      log_error("FILE_HISTORY_meshfield_setup",*)   "Any mesh (mesh1d/2d/3d) are not specified."
      call prc_abort
    end if
 
    file_history_filemeshfiled_disable = .false. 
 
    return
  end subroutine file_history_meshfield_setup
 
!OCL SERIAL
  subroutine file_history_meshfield_write()
    implicit none
    !-------------------------------------------------
 
    call file_history_write
    return
  end subroutine file_history_meshfield_write
 
!OCL SERIAL
  subroutine file_history_meshfield_finalize()
    implicit none
    !-------------------------------------------------
 
    call file_history_finalize()
    return
  end subroutine file_history_meshfield_finalize
 
  !-- 1D
 
!OCL SERIAL
  subroutine file_history_meshfield_put1d(hstid, field1d)
    use scale_file_common_meshfield, only: &
      file_common_meshfield_put_field1d_cartesbuf
    implicit none
    integer, intent(in) :: hstid
    class(meshfield1d), intent(in) :: field1d
 
    real(RP), allocatable :: buf(:)
    !-------------------------------------------------
      
    allocate( buf(dims1d_size(1)) )
 
    call file_common_meshfield_put_field1d_cartesbuf( mesh1d, field1d, buf(:) )
    call file_history_put(hstid, buf)
 
    return
  end subroutine file_history_meshfield_put1d
 
!OCL SERIAL
  subroutine file_history_meshfield_in1d( field1d, desc, standard_name )
    implicit none
    class(meshfield1d), intent(in) :: field1d
    character(len=*), intent(in) :: desc
    character(len=*), intent(in), optional :: standard_name
 
    integer :: hstid
    logical :: do_put
    !-------------------------------------------------
 
    call history_in_regvar( hstid, do_put,    & ! (out)
      field1d, desc, 1, standard_name, 'XYZ'  ) ! (in)
 
    if ( do_put ) call file_history_meshfield_put( hstid, field1d )
 
    return
  end subroutine file_history_meshfield_in1d
  
  !-- 2D
 
!OCL SERIAL
  subroutine file_history_meshfield_put2d(hstid, field2d)
    use scale_file_common_meshfield, only: &
      file_common_meshfield_put_field2d_cartesbuf,            &
      file_common_meshfield_put_field2d_cubedsphere_cartesbuf
 
    implicit none
    integer, intent(in) :: hstid
    class(meshfield2d), intent(in) :: field2d
 
    real(RP), allocatable :: buf(:,:)
    !-------------------------------------------------
 
    allocate( buf(dims2d_size(1),dims2d_size(2)) )
    
    if ( associated(mesh2d) ) then
      call file_common_meshfield_put_field2d_cartesbuf( mesh2d, field2d, buf(:,:) )
    else if ( associated(meshcubedsphere2d) ) then
      call file_common_meshfield_put_field2d_cubedsphere_cartesbuf( &
        meshcubedsphere2d, field2d, buf(:,:) )
    end if
    call file_history_put(hstid, buf)
 
    return
  end subroutine file_history_meshfield_put2d
 
!OCL SERIAL
  subroutine file_history_meshfield_in2d( field2d, desc, standard_name )
    implicit none
    class(meshfield2d), intent(in) :: field2d
    character(len=*), intent(in) :: desc
    character(len=*), intent(in), optional :: standard_name
 
    integer :: hstid
    logical :: do_put
    !-------------------------------------------------
 
    call history_in_regvar( hstid, do_put,  & ! (out)
      field2d, desc, 2, standard_name, 'XY' ) ! (in)
 
    if ( do_put ) call file_history_meshfield_put( hstid, field2d )
 
    return
  end subroutine file_history_meshfield_in2d
 
  !-- 3D
 
!OCL SERIAL
  subroutine file_history_meshfield_put3d(hstid, field3d)
    use scale_file_common_meshfield, only: &
      file_common_meshfield_put_field3d_cartesbuf,            &
      file_common_meshfield_put_field3d_cubedsphere_cartesbuf
 
    implicit none
    integer, intent(in) :: hstid
    class(meshfield3d), intent(in) :: field3d
 
    real(RP), allocatable :: buf(:,:,:)
 
    !-------------------------------------------------
 
    allocate( buf(dims3d_size(1,1),dims3d_size(2,1),dims3d_size(3,1)) )
    if ( associated(mesh3d) ) then
      call file_common_meshfield_put_field3d_cartesbuf( mesh3d, field3d, buf(:,:,:) )
    else if ( associated(meshcubedsphere3d) ) then
      call file_common_meshfield_put_field3d_cubedsphere_cartesbuf( &
        meshcubedsphere3d, field3d, buf(:,:,:) )
    end if
    call file_history_put(hstid, buf)
 
    return
  end subroutine file_history_meshfield_put3d
  
!OCL SERIAL
  subroutine file_history_meshfield_in3d( field3d, desc, standard_name )
    implicit none
    class(meshfield3d), intent(in) :: field3d
    character(len=*), intent(in) :: desc
    character(len=*), intent(in), optional :: standard_name
 
    integer :: hstid
    logical :: do_put
    !-------------------------------------------------
 
    call history_in_regvar( hstid, do_put,   & ! (out)
      field3d, desc, 3, standard_name, 'XYZ' ) ! (in)
 
    if ( do_put ) call file_history_meshfield_put( hstid, field3d )
 
    return
  end subroutine file_history_meshfield_in3d
 
!----------------
 
!OCL SERIAL
  subroutine history_in_regvar( hstid, do_put,  &
    field, desc, ndim, standard_name, dim_type  )
 
    use scale_file_history, only: &
      file_history_reg,           &
      file_history_query
    
    implicit none
 
    integer, intent(out) :: hstid
    logical, intent(out) :: do_put
    class(meshfieldbase), intent(in) :: field  
    character(len=*), intent(in) :: desc
    integer, intent(in)          :: ndim
    character(len=*), intent(in), optional :: standard_name
    character(len=*), intent(in), optional :: dim_type
 
    logical, parameter     :: fill_halo = .false.
    !------------------------------------------------------
 
    hstid = -1
    do_put = .false.
 
    if ( file_history_filemeshfiled_disable ) return
 
    ! Check whether the item has been already registered
    call file_history_reg( field%varname, desc, field%unit, & ! [IN]
                           hstid,                           & ! [OUT]
                           standard_name=standard_name,     & ! [IN]
                           ndims=ndim,                      & ! [IN]
                           dim_type=dim_type,               & ! [IN]
                           fill_halo=fill_halo              ) ! [IN]
    
    if ( hstid < 0 ) return
 
    ! Check whether it is time to input the item
    call file_history_query( hstid, do_put ) ! [IN], [OUT]
    
    return
  end subroutine history_in_regvar
 
!OCL SERIAL
  subroutine set_dim_axis1d()
    use scale_file_common_meshfield, only: &
      file_common_meshfield_diminfo,    &
      file_common_meshfield_get_dims1d, &
      file_common_meshfield_get_axis1d
    use scale_mesh_base1d, only: &
      dimtype_num => meshbase1d_dimtype_num, &
      dimtype_x   => meshbase1d_dimtypeid_x
  
    implicit none
 
    type(file_common_meshfield_diminfo) :: dimsinfo(DIMTYPE_NUM)
    real(RP), allocatable :: x(:)
    integer :: start(1,1), count(1,1)
    character(len=H_SHORT) :: dims(1,1)
    integer :: n, ndim
    !-------------------------------------------------
    
    call file_common_meshfield_get_dims1d( mesh1d, & ! (in)
      dimsinfo(:) )                                  ! (out)
    
    dims1d_size(1) = dimsinfo(dimtype_x)%size
    allocate( x(dims1d_size(1)) )
    call file_common_meshfield_get_axis1d( mesh1d, dimsinfo, & ! (in)
      x )                                                      ! (out)
 
    start(:,:) = 1
    do n=1, dimtype_num
      ndim = dimsinfo(n)%ndim
      dims(1:ndim,1)  = dimsinfo(n)%dims(1:ndim)
      count(1:ndim,1) = dimsinfo(n)%count(1:ndim)
      call file_history_set_dim ( dimsinfo(n)%type, ndim, 1, dims(1:ndim,:), zs(:), start(1:ndim,:), count(1:ndim,:))
    end do
    
    call file_history_set_axis( dimsinfo(dimtype_x)%name, dimsinfo(dimtype_x)%desc, &
      dimsinfo(dimtype_x)%unit, dimsinfo(dimtype_x)%name, x(:))
 
    return
  end subroutine set_dim_axis1d
 
!OCL SERIAL
  subroutine set_dim_axis2d()
    use scale_file_common_meshfield, only: &
      file_common_meshfield_diminfo,       &
      file_common_meshfield_get_dims2d,    &
      file_common_meshfield_get_axis2d
    use scale_mesh_base2d, only: &
      dimtype_num => meshbase2d_dimtype_num, &
      dimtype_x   => meshbase2d_dimtypeid_x, &
      dimtype_y   => meshbase2d_dimtypeid_y
   
    implicit none
 
    type(file_common_meshfield_diminfo) :: dimsinfo(DIMTYPE_NUM)
    real(RP), allocatable :: x(:), y(:)
    integer :: start(2,1), count(2,1)
    character(len=H_SHORT) :: dims(2,1)
    integer :: n, ndim
    !-------------------------------------------------
    
    call file_common_meshfield_get_dims2d( mesh2d, & ! (in)
      dimsinfo(:) )                                  ! (out)
    
    dims2d_size(1) = dimsinfo(dimtype_x)%size
    dims2d_size(2) = dimsinfo(dimtype_y)%size
    allocate( x(dims2d_size(1)), y(dims2d_size(2)) )
    call file_common_meshfield_get_axis2d( mesh2d, dimsinfo, & ! (in)
      x, y )                                                   ! (out)
 
    start(:,:) = 1
 
    do n=1, dimtype_num
      ndim = dimsinfo(n)%ndim
      dims(1:ndim,1)  = dimsinfo(n)%dims(1:ndim)
      count(1:ndim,1) = dimsinfo(n)%count(1:ndim)
      call file_history_set_dim ( dimsinfo(n)%type, ndim, 1, dims(1:ndim,:), zs(:), start(1:ndim,:), count(1:ndim,:))
    end do
    
    call file_history_set_axis( dimsinfo(dimtype_x)%name, dimsinfo(dimtype_x)%desc, dimsinfo(dimtype_x)%unit, dimsinfo(dimtype_x)%name, x(:))
    call file_history_set_axis( dimsinfo(dimtype_y)%name, dimsinfo(dimtype_y)%desc, dimsinfo(dimtype_y)%unit, dimsinfo(dimtype_y)%name, y(:))
    
    return
  end subroutine set_dim_axis2d
 
!OCL SERIAL
  subroutine set_dim_axis3d()
    use scale_file_common_meshfield, only: &
      file_common_meshfield_diminfo,       &
      file_common_meshfield_get_dims3d,    &
      file_common_meshfield_get_axis3d
    use scale_mesh_base3d, only: &
      dimtype_num => meshbase3d_dimtype_num, &
      dimtype_x   => meshbase3d_dimtypeid_x, &
      dimtype_y   => meshbase3d_dimtypeid_y, &
      dimtype_z   => meshbase3d_dimtypeid_z
 
    implicit none
 
    type(file_common_meshfield_diminfo) :: dimsinfo(DIMTYPE_NUM)
    real(RP), allocatable :: x(:), y(:), z(:)
    integer :: start(3,1), count(3,1)
    character(len=H_SHORT) :: dims(3,1)
    integer :: n, ndim
    !-------------------------------------------------
    
    call file_common_meshfield_get_dims3d( mesh3d, & ! (in)
      dimsinfo(:) )                                  ! (out)
  
    dims2d_size(1) = dimsinfo(dimtype_x)%size
    dims2d_size(2) = dimsinfo(dimtype_y)%size  
    dims3d_size(1,1) = dimsinfo(dimtype_x)%size
    dims3d_size(2,1) = dimsinfo(dimtype_y)%size
    dims3d_size(3,1) = dimsinfo(dimtype_z)%size
    allocate( x(dims3d_size(1,1)), y(dims3d_size(2,1)), z(dims3d_size(3,1)) )
    call file_common_meshfield_get_axis3d( mesh3d, dimsinfo, & ! (in)
      x, y, z )                                                ! (out)
 
    start(:,:) = 1
    do n=1, dimtype_num
      ndim = dimsinfo(n)%ndim
      dims(1:ndim,1)  = dimsinfo(n)%dims(1:ndim)
      count(1:ndim,1) = dimsinfo(n)%count(1:ndim)
      call file_history_set_dim ( dimsinfo(n)%type, ndim, 1, dims(1:ndim,:), zs(:), start(1:ndim,:), count(1:ndim,:))
    end do
    
    call file_history_set_axis( dimsinfo(dimtype_x)%name, dimsinfo(dimtype_x)%desc, dimsinfo(dimtype_x)%unit, dimsinfo(dimtype_x)%name, x(:) )
    call file_history_set_axis( dimsinfo(dimtype_y)%name, dimsinfo(dimtype_y)%desc, dimsinfo(dimtype_y)%unit, dimsinfo(dimtype_y)%name, y(:) )
    call file_history_set_axis( dimsinfo(dimtype_z)%name, dimsinfo(dimtype_z)%desc, dimsinfo(dimtype_z)%unit, dimsinfo(dimtype_z)%name, z(:), &
      down=dimsinfo(dimtype_z)%positive_down(1) )
 
    return
  end subroutine set_dim_axis3d
 
!OCL SERIAL
  subroutine set_dim_axis2d_cubedsphere()
    use scale_file_common_meshfield, only: &
      file_common_meshfield_diminfo,  &
      file_common_meshfield_get_dims, &
      file_common_meshfield_get_axis
    use scale_mesh_base2d, only: &
      dimtype_num => meshbase2d_dimtype_num, &
      dimtype_x  => meshbase2d_dimtypeid_x,  &
      dimtype_y  => meshbase2d_dimtypeid_y
 
    implicit none
 
    type(file_common_meshfield_diminfo) :: dimsinfo(DIMTYPE_NUM)
    real(RP), allocatable :: x(:), y(:)
    integer :: start(2,1), count(2,1)
    character(len=H_SHORT) :: dims(2,1)
    integer :: n, ndim
    !-------------------------------------------------
    
    call file_common_meshfield_get_dims( meshcubedsphere2d, & ! (in)
      dimsinfo(:) )                                           ! (out)
    
    dims2d_size(1) = dimsinfo(dimtype_x)%size
    dims2d_size(2) = dimsinfo(dimtype_y)%size
    allocate( x(dims2d_size(1)), y(dims2d_size(2)) )
    
    call file_common_meshfield_get_axis( meshcubedsphere2d, dimsinfo, & ! (in)
      x, y )                                                            ! (out)
    
    start(:,:) = 1
 
    do n=1, dimtype_num
      ndim = dimsinfo(n)%ndim
      dims(1:ndim,1)  = dimsinfo(n)%dims(1:ndim)
      count(1:ndim,1) = dimsinfo(n)%count(1:ndim)
      call file_history_set_dim ( dimsinfo(n)%type, ndim, 1, dims(1:ndim,:), zs(:), start(1:ndim,:), count(1:ndim,:))
    end do
    
    call file_history_set_axis( dimsinfo(dimtype_x)%name, dimsinfo(dimtype_x)%desc, dimsinfo(dimtype_x)%unit, dimsinfo(dimtype_x)%name, x(:))
    call file_history_set_axis( dimsinfo(dimtype_y)%name, dimsinfo(dimtype_y)%desc, dimsinfo(dimtype_y)%unit, dimsinfo(dimtype_y)%name, y(:))
    
    return
  end subroutine set_dim_axis2d_cubedsphere
 
!OCL SERIAL
  subroutine set_dim_axis3d_cubedsphere()
    use scale_file_common_meshfield, only: &
      file_common_meshfield_diminfo,  &
      file_common_meshfield_get_dims, &
      file_common_meshfield_get_axis
    use scale_mesh_base3d, only: &
      dimtype_num => meshbase3d_dimtype_num, &
      dimtype_x   => meshbase3d_dimtypeid_x, &
      dimtype_y   => meshbase3d_dimtypeid_y, &
      dimtype_z   => meshbase3d_dimtypeid_z
 
    implicit none
 
    type(file_common_meshfield_diminfo) :: dimsinfo(DIMTYPE_NUM)
    real(RP), allocatable :: x(:), y(:), z(:)
    integer :: start(3,1), count(3,1)
    character(len=H_SHORT) :: dims(3,1)
    integer :: n, ndim
    !-------------------------------------------------
    
    call file_common_meshfield_get_dims( meshcubedsphere3d, & ! (in)
      dimsinfo(:) )                                           ! (out)
 
    dims2d_size(1) = dimsinfo(dimtype_x)%size
    dims2d_size(2) = dimsinfo(dimtype_y)%size
    dims3d_size(1,1) = dimsinfo(dimtype_x)%size
    dims3d_size(2,1) = dimsinfo(dimtype_y)%size
    dims3d_size(3,1) = dimsinfo(dimtype_z)%size
    allocate( x(dims3d_size(1,1)), y(dims3d_size(2,1)), z(dims3d_size(3,1)) )
    call file_common_meshfield_get_axis( meshcubedsphere3d, dimsinfo, & ! (in)
      x, y, z )                                                         ! (out)
 
    start(:,:) = 1
    do n=1, dimtype_num
      ndim = dimsinfo(n)%ndim
      dims(1:ndim,1)  = dimsinfo(n)%dims(1:ndim)
      count(1:ndim,1) = dimsinfo(n)%count(1:ndim)
      call file_history_set_dim ( dimsinfo(n)%type, ndim, 1, dims(1:ndim,:), zs(:), start(1:ndim,:), count(1:ndim,:))
    end do
    
    call file_history_set_axis( dimsinfo(dimtype_x)%name, dimsinfo(dimtype_x)%desc, dimsinfo(dimtype_x)%unit, dimsinfo(dimtype_x)%name, x(:) )
    call file_history_set_axis( dimsinfo(dimtype_y)%name, dimsinfo(dimtype_y)%desc, dimsinfo(dimtype_y)%unit, dimsinfo(dimtype_y)%name, y(:) )
    call file_history_set_axis( dimsinfo(dimtype_z)%name, dimsinfo(dimtype_z)%desc, dimsinfo(dimtype_z)%unit, dimsinfo(dimtype_z)%name, z(:), &
      down=dimsinfo(dimtype_z)%positive_down(1) )
      
    return
  end subroutine set_dim_axis3d_cubedsphere
 
!----------------
 
end module scale_file_history_meshfield