mod_atmos_phy_tb_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Atmosphere / Physics / sub-grid scale turbulence
!!
!! @par Description
!!          Container for variables with sub-grid scale turbulence model
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_atmos_phy_tb_vars
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
  use scale_tracer, only: qa
 
  use scale_element_base, only: elementbase3d
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: &
    meshbase3d,                              &
    dimtype_xyz  => meshbase3d_dimtypeid_xyz
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_3d, only: localmesh3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
  use scale_meshfield_base, only: &
    meshfieldbase, meshfield2d, meshfield3d
 
  use scale_file_restart_meshfield, only: &
    file_restart_meshfield_component
  
  use scale_meshfieldcomm_base, only: meshfieldcontainer
  
  use scale_model_var_manager, only: &
    modelvarmanager, variableinfo
  use scale_model_mesh_manager, only: modelmeshbase
    
  use scale_atm_phy_tb_dgm_common, only: &
    atmos_phy_tb_aux_num, atmos_phy_tb_aux_scalar_num, atmos_phy_tb_aux_hvec_num, &
    atmos_phy_tb_aux_htensor_num,                                                    &
    atmos_phy_tb_diag_num,                                                           &
    atmos_phy_tb_tends_num1, &
    tb_momx_t_vid => atmos_phy_tb_momx_t_id,tb_momy_t_vid => atmos_phy_tb_momy_t_id, &
    tb_momz_t_vid => atmos_phy_tb_momz_t_id, tb_rhot_t_vid => atmos_phy_tb_rhot_t_id
 
  use mod_atmos_mesh, only: atmosmesh
 
  !-----------------------------------------------------------------------------
  implicit none
  private
 
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
 
  !> Derived type to manage variables with atmospheric SGS turbulent component
  type, public :: atmosphytbvars
    type(meshfield3d), allocatable :: tends(:)
    type(modelvarmanager) :: tends_manager
 
    type(meshfield3d), allocatable :: auxvars(:)
    type(modelvarmanager) :: auxvars_manager
    integer :: auxvars_commid
 
    type(meshfield3d), allocatable :: diagvars(:)
    type(modelvarmanager) :: diagvars_manager
 
    integer :: tends_num_tot 
  contains
    procedure :: init => atmosphytbvars_init
    procedure :: final => atmosphytbvars_final
    procedure :: history => atmosphytbvars_history
  end type atmosphytbvars
 
  public :: atmosphytbvars_getlocalmeshfields_tend
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures
  !
  !-------------------
 
contains
!> Setup an object to manage variables with atmospheric SGS turbulent component
!!
!! @param model_mesh Object to manage computational mesh of atmospheric model 
!OCL SERIAL
  subroutine atmosphytbvars_init( this, model_mesh )
 
    use scale_tracer, only: &
      tracer_name, tracer_desc, tracer_unit    
    use scale_atm_phy_tb_dgm_common, only: &
      atm_phy_tb_dgm_common_setup_variables
    
    implicit none
    class(atmosphytbvars), target, intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
 
    integer :: iv
    integer :: iq
    logical :: reg_file_hist
 
    class(atmosmesh), pointer :: atm_mesh
    class(meshbase2d), pointer :: mesh2D
    class(meshbase3d), pointer :: mesh3D
    !--------------------------------------------------
 
    log_info('AtmosPhyTbVars_Init',*)
 
    this%TENDS_NUM_TOT = atmos_phy_tb_tends_num1 + qa
 
    !- Initialize auxiliary and diagnostic variables
 
    nullify( atm_mesh )
    select type(model_mesh)
    class is (atmosmesh)
      atm_mesh => model_mesh
    end select
    mesh3d => atm_mesh%ptr_mesh
    
    call mesh3d%GetMesh2D( mesh2d )
 
    !- Get variable information
    ! call atm_phy_tb_dgm_common_get_varinfo( auxvar_info, diagvar_info, tbtend_info ) ! (out)
 
    !- Initialize objects to variables with turbulent model
 
    call this%tends_manager%Init()
    call this%auxvars_manager%Init()
    call this%diagvars_manager%Init()
 
    allocate( this%diagvars(atmos_phy_tb_diag_num) )
    allocate( this%tends(this%TENDS_NUM_TOT) )
    allocate( this%auxvars(atmos_phy_tb_aux_num) )
 
    call atm_phy_tb_dgm_common_setup_variables( &
      this%tends, this%auxvars, this%diagvars,                         & ! (inout)
      this%tends_manager, this%auxvars_manager, this%diagvars_manager, & ! (inout)
      this%TENDS_NUM_TOT, mesh3d )                                       ! (in)
 
    !- Setup communication
 
    call atm_mesh%Create_communicator( &
      atmos_phy_tb_aux_scalar_num, atmos_phy_tb_aux_hvec_num, & ! (in)
      atmos_phy_tb_aux_htensor_num,                           & ! (in)
      this%auxvars_manager,            & ! (inout)
      this%auxvars(:),                 & ! (in)
      this%auxvars_commid              ) ! (out)
 
    return
  end subroutine atmosphytbvars_init
 
!> Finalize an object to manage variables with atmospheric SGS turbulent component
!OCL SERIAL
  subroutine atmosphytbvars_final( this )
    implicit none
    class(atmosphytbvars), intent(inout) :: this
    !--------------------------------------------------
 
    log_info('AtmosPhyTbVars_Final',*)
 
    call this%tends_manager%Final()
    deallocate( this%tends )
 
    call this%auxvars_manager%Final()
    deallocate( this%auxvars )
 
    call this%diagvars_manager%Final()
    deallocate( this%diagvars )
 
    return
  end subroutine atmosphytbvars_final
 
!OCL SERIAL
  subroutine atmosphytbvars_getlocalmeshfields_tend( domID, mesh, tb_tends_list, &
    tb_MOMX_t, tb_MOMY_t, tb_MOMZ_t, tb_RHOT_t, tb_RHOQ_t,                       &
    lcmesh3D                                                                     &
    )
 
    use scale_mesh_base, only: meshbase
    use scale_meshfield_base, only: meshfieldbase
    implicit none
 
    integer, intent(in) :: domid
    class(meshbase), intent(in) :: mesh
    class(modelvarmanager), intent(inout) :: tb_tends_list
    class(localmeshfieldbase), pointer, intent(out) :: tb_momx_t
    class(localmeshfieldbase), pointer, intent(out) :: tb_momy_t
    class(localmeshfieldbase), pointer, intent(out) :: tb_momz_t
    class(localmeshfieldbase), pointer, intent(out) :: tb_rhot_t
    type(localmeshfieldbaselist), intent(out), optional :: tb_rhoq_t(:)
    class(localmesh3d), pointer, intent(out), optional :: lcmesh3d
 
    class(meshfieldbase), pointer :: field   
    class(localmeshbase), pointer :: lcmesh
 
    integer :: iq
    !-------------------------------------------------------
 
    !--
    call tb_tends_list%Get(tb_momx_t_vid, field)
    call field%GetLocalMeshField(domid, tb_momx_t)
 
    call tb_tends_list%Get(tb_momy_t_vid, field)
    call field%GetLocalMeshField(domid, tb_momy_t)
 
    call tb_tends_list%Get(tb_momz_t_vid, field)
    call field%GetLocalMeshField(domid, tb_momz_t)
 
    call tb_tends_list%Get(tb_rhot_t_vid, field)
    call field%GetLocalMeshField(domid, tb_rhot_t)
 
    !---
    if ( present(tb_rhoq_t) ) then
      do iq = 1, size(tb_rhoq_t)
        call tb_tends_list%Get(atmos_phy_tb_tends_num1 + iq, field)
        call field%GetLocalMeshField(domid, tb_rhoq_t(iq)%ptr)
      end do    
    end if
 
    if (present(lcmesh3d)) then
      call mesh%GetLocalMesh( domid, lcmesh )
      nullify( lcmesh3d )
 
      select type(lcmesh)
      type is (localmesh3d)
        if (present(lcmesh3d)) lcmesh3d => lcmesh
      end select
    end if
 
    return
  end subroutine atmosphytbvars_getlocalmeshfields_tend
 
!OCL SERIAL
  subroutine atmosphytbvars_history( this )
    use scale_file_history_meshfield, only: file_history_meshfield_put
    implicit none
    class(atmosphytbvars), intent(inout) :: this
  
    integer :: v
    integer :: hst_id
    type(meshfield3d) :: tmp_field
    class(meshbase3d), pointer :: mesh3d
    !-------------------------------------------------------------------------
 
    mesh3d => this%auxvars(1)%mesh
 
    do v = 1, this%TENDS_NUM_TOT
      hst_id = this%tends(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%tends(v) )
    end do
 
    do v = 1, atmos_phy_tb_aux_num
      hst_id = this%auxvars(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%auxvars(v) )
    end do
 
    do v = 1, atmos_phy_tb_diag_num
      hst_id = this%diagvars(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%diagvars(v) )
    end do
 
    return
  end subroutine atmosphytbvars_history
 
end  module mod_atmos_phy_tb_vars