mod_atmos_mesh_gm Module Reference

module Atmosphere / Mesh More...

Data Types
type	atmosmeshgm
	Derived type to manage a computational mesh of global atmospheric model. More...

Functions/Subroutines
subroutine	atmosmeshgm_init (this)
	Initialize a object to manage computational mesh.

Detailed Description

module Atmosphere / Mesh

Description

Module for mesh with atmospheric global model

Author

Yuta kawai, Team SCALE

NAMELIST

• PARAM_ATMOS_MESH

  name	type	default value	comment
  SHALLOW_ATM_APPROX_FLAG	logical	.true.	Flag whether the shallow atmosphere approximation is applied
  DOM_ZMIN	real(RP)	0.0_RP	Minimum vertical coordinate value of the computational domain
  DOM_ZMAX	real(RP)	10.0E3_RP	Maximum vertical coordinate value of the computational domain
  FZ	real(RP), dimension(FZ_NMAX)		Values of the vertically computational coordinate at the element boundaries
  ISPERIODICZ	logical	.false.	Flag whether a periodic boundary condition is applied in the vertical direction
  NEGX	integer	2	Number of finite element in the y-coordinate direction in each panel of the cubed-sphere mesh
  NEGY	integer	2	Number of finite element in the y-coordinate direction in each panel of the cubed-sphere mesh
  NEZ	integer	2	Number of finite element in the vertical direction in each MPI process
  NLOCALMESHPERPRC	integer	6	Number of local mesh per MPI process
  NPRC	integer	1	Total number of MPI process
  POLYORDER_H	integer	2	Polynomial order for the horizontal direction
  POLYORDER_V	integer	2	Polynomial order for the z-direction
  LUMPEDMASSMATFLAG	logical	.false.	Flag whether a mass lumping is applied
  ELEMENT_OPERATION_TYPE	character(len=H_SHORT)	'General'	General or TensorProd3D
  SPMV_STORAGE_FORMAT	character(len=H_SHORT)	'ELL'	CSR or ELL
  VERTICAL_COORD_NAME	character(len=H_MID)	"TERRAIN_FOLLOWING"	Type of the vertical coordinate
  TOPO_IN_BASENAME	character(len=H_LONG)	''	Basename of the input file
  TOPO_IN_VARNAME	character(len=H_MID)	'topo'	Variable name of topography in the input file
  COMM_USE_MPI_PC	logical	.false.	Flag whether persistent communication is used in MPI

  
  

History Output

No history output

Function/Subroutine Documentation

atmosmeshgm_init()

subroutine mod_atmos_mesh_gm::atmosmeshgm_init

(

class(atmosmeshgm), intent(inout), target

this

)

Initialize a object to manage computational mesh.

Definition at line 82 of file mod_atmos_mesh_gm.F90.

    use scale_const, only: &
      rplanet => const_radius
    use scale_mesh_base2d, only: &
      mftype2d_xy => meshbase2d_dimtypeid_xy
    use scale_meshutil_vcoord, only: &
      meshutil_get_vcoord_typeid
    
    implicit none
    class(AtmosMeshGM), target, intent(inout) :: this
 
    real(RP) :: dom_zmin          = 0.0_rp      
    real(RP) :: dom_zmax          = 10.0e3_rp   
    logical  :: isPeriodicZ       = .false.     
  
    integer, parameter :: FZ_nmax = 1000
    real(RP) :: FZ(FZ_nmax)
 
    !* Global
    logical :: SHALLOW_ATM_APPROX_FLAG = .true.  
    integer  :: NeGX               = 2
    integer  :: NeGY               = 2
    integer  :: NeZ                = 2
    integer  :: NLocalMeshPerPrc   = 6
    integer  :: Nprc               = 1
    integer  :: PolyOrder_h        = 2
    integer  :: PolyOrder_v        = 2
    logical  :: LumpedMassMatFlag  = .false.     
 
    character(len=H_LONG) :: TOPO_IN_BASENAME    = ''
    character(len=H_MID)  :: TOPO_IN_VARNAME     = 'topo'
    character(len=H_MID)  :: VERTICAL_COORD_NAME = "TERRAIN_FOLLOWING"
 
    logical :: COMM_USE_MPI_PC    = .false.      
 
    character(len=H_SHORT) :: Element_operation_type = 'General'
    character(len=H_SHORT) :: SpMV_storage_format    = 'ELL'
    
    namelist / param_atmos_mesh / &
      shallow_atm_approx_flag,                     &
      dom_zmin, dom_zmax,                          &
      fz, isperiodicz,                             &
      negx, negy, nez, nlocalmeshperprc, nprc,     &
      polyorder_h, polyorder_v, lumpedmassmatflag, &
      element_operation_type,                      &
      spmv_storage_format,                         &
      vertical_coord_name,                         &
      topo_in_basename, topo_in_varname,           &
      comm_use_mpi_pc
    
    integer :: k
    logical :: is_spec_FZ
    
    integer :: ierr
 
    type(FILE_base_meshfield) :: file_topo
    !-------------------------------------------
 
    log_newline
    log_info("ATMOS_MESH_setup",*) 'Setup'
 
    fz(:) = -1.0_rp
 
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_mesh,iostat=ierr)
    if( ierr < 0 ) then !--- missing
      log_info("ATMOS_MESH_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
      log_error("ATMOS_MESH_setup",*) 'Not appropriate names in namelist PARAM_ATM_MESH. Check!'
      call prc_abort
    endif
    log_nml(param_atmos_mesh)
 
    !----
 
    !- Setup the element
 
    call this%element%Init( polyorder_h, polyorder_v, lumpedmassmatflag )
    call this%element_v1D%Init( polyorder_v, lumpedmassmatflag )
 
    !- Setup the mesh
 
    is_spec_fz = .true.
    do k=1, nez+1
      if (fz(k) < 0.0_rp) then
        is_spec_fz = .false.
      end if
    end do
    if (is_spec_fz) then
      call this%mesh%Init( &
        negx, negy, nez, rplanet, dom_zmin, dom_zmax,          &
        this%element, nlocalmeshperprc, nproc=nprc,            &
        fz=fz(1:nez+1), shallow_approx=shallow_atm_approx_flag )
    else
      call this%mesh%Init( &
        negx, negy, nez, rplanet, dom_zmin, dom_zmax, &
        this%element, nlocalmeshperprc, nproc=nprc,   &
        shallow_approx=shallow_atm_approx_flag        )
    end if
    
    call this%mesh%Generate()
    
    !-
 
    call this%AtmosMesh_Init( this%mesh )
    call this%PrepairElementOperation( element_operation_type, spmv_storage_format )
 
    !- Set topography & vertical coordinate
    
    if ( topo_in_basename /= '' ) then
      log_info("ATMOS_MESH_setup",*) 'Read topography data'
 
      call file_topo%Init(1, meshcubedsphere2d=this%mesh%mesh2D )
      call file_topo%Open( topo_in_basename, myrank=prc_myrank )
      call file_topo%Read_Var( mftype2d_xy, topo_in_varname, this%topography%topo )
      call file_topo%Close()
      call file_topo%Final()
    end if
 
    this%vcoord_type_id = meshutil_get_vcoord_typeid( vertical_coord_name )
    call this%Setup_vcoordinate()
 
    !-
    this%comm_use_mpi_pc = comm_use_mpi_pc
 
    return

References mod_atmos_mesh::atm_mesh_max_commnuicator_num, scale_cubedsphere_coord_cnv::cubedspherecoordcnv_cs2lonlatvec(), scale_mesh_base2d::meshbase2d_dimtypeid_xy, and scale_meshutil_vcoord::meshutil_get_vcoord_typeid().