mod_mktopo.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scalelib.h"
module mod_mktopo
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_prc
 
  use scale_const, only: &
    pi => const_pi,          &
    rplanet => const_radius
 
  use scale_element_base, only: &
    elementbase2d, elementbase3d
  use scale_element_hexahedral, only: hexahedralelement
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: meshbase3d
  use scale_localmeshfield_base, only: localmeshfieldbase
  use scale_meshfield_base, only: meshfield2d
  use scale_mesh_topography, only: meshtopography
 
  use mod_atmos_component, only: &
    atmoscomponent
  use mod_atmos_mesh, only: atmosmesh
 
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: mktopo_setup
  public :: mktopo
  public :: mktopo_write
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  
  integer, public :: mktopo_type                          = -1
  integer, parameter, public :: i_ignore                  = 0
  integer, parameter, public :: i_input_file              = 1
  integer, parameter, public :: i_flat                    = 2
  integer, parameter, public :: i_bellshape               = 3
  integer, parameter, public :: i_scaer                   = 4
  integer, parameter, public :: i_bellshape_global        = 5
  integer, parameter, public :: i_scaher_global           = 6
  integer, parameter, public :: i_barocwave_global_jw2006 = 7  
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
 
  private :: mktopo_flat
  private :: mktopo_bellshape
  private :: mktopo_schaer_type_mountain
  private :: mktopo_bellshape_global
  private :: mktopo_barocwave_global_jw2006
 
  !-----------------------------------------------------------------------------
  !
  !++ Private variables
  !
  character(len=H_LONG)  :: out_basename = ''
  character(len=H_MID)   :: out_varname  = 'topo'
  character(len=H_MID)   :: out_title    = 'SCALE-DG TOPOGRAPHY'
  character(len=H_SHORT) :: out_dtype    = 'DEFAULT'
  !-----------------------------------------------------------------------------  
contains
  !-----------------------------------------------------------------------------
!OCL SERIAL
  subroutine mktopo_setup
    implicit none
 
    character(len=H_SHORT) :: toponame = 'NONE'
 
    namelist / param_mktopo /  &
      toponame,                  &
      out_basename, out_varname, &
      out_title, out_dtype
 
 
    integer :: ierr
    !---------------------------------------------------------------------------
 
    log_newline
    log_info("MKTOPO_setup",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_mktopo,iostat=ierr)
    if( ierr < 0 ) then !--- missing
      log_info("MKTOPO_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
      log_error("MKTOPO_setup",*) 'Not appropriate names in namelist PARAM_MKTOPO. Check!'
      call prc_abort
    endif
    log_nml(param_mktopo)
 
    select case(trim(toponame))
    case('NONE')
      mktopo_type = i_ignore
    case('INPUT_FILE')
      mktopo_type = i_input_file
    case('FLAT')
      mktopo_type = i_flat  
    case('BELLSHAPE')
      mktopo_type = i_bellshape
    case('SCHAER')
      mktopo_type = i_scaer
    case('BELLSHAPE_GLOBAL')
      mktopo_type = i_bellshape_global
    case('SCHAER_GLOBAL')
      mktopo_type = i_scaher_global
    case('BAROCWAVE_GLOBAL_JW2006')
      mktopo_type = i_barocwave_global_jw2006      
    case default
      log_error("MKTOPO_setup",*) 'Not appropriate toponame. Check!', toponame
      call prc_abort      
    end select
    
    return
  end subroutine mktopo_setup
 
  !-----------------------------------------------------------------------------
!OCL SERIAL
  subroutine mktopo( output, model_mesh, topography )
    use scale_model_var_manager, only: modelvarmanager
    implicit none
 
    logical, intent(out) :: output
    class(atmosmesh), target, intent(in) :: model_mesh
    class(meshtopography), intent(inout) :: topography
 
    integer :: n
    integer :: ke
    class(localmesh3d), pointer :: lcmesh3d
    class(meshbase3d), pointer :: mesh
    class(localmesh2d), pointer :: lcmesh2d
    class(meshbase2d), pointer :: mesh2d
    !---------------------------------------------------------------------------
 
    mesh => model_mesh%ptr_mesh
 
    if ( mktopo_type == i_ignore ) then
      log_newline
      log_progress(*) 'skip  making topography data'
      output = .false.
    else
      log_newline
      log_progress(*) 'start making topography data'
 
      call prof_rapstart('_MkTOPO_main', 3)   
      
      call mesh%GetMesh2D( mesh2d )
 
      select case( mktopo_type )
      case ( i_input_file )
        call mktopo_input_file( mesh2d, topography%topo )
      case ( i_flat )
        call mktopo_flat( mesh2d, topography%topo )
      case ( i_bellshape )
        call mktopo_bellshape( mesh2d, topography%topo )
      case ( i_scaer )
        call mktopo_schaer_type_mountain( mesh2d, topography%topo )
      case ( i_bellshape_global )
        call mktopo_bellshape_global( mesh2d, topography%topo )
      case ( i_scaher_global )
        call mktopo_schaer_type_global( mesh2d, topography%topo )        
      case ( i_barocwave_global_jw2006 )
        call mktopo_barocwave_global_jw2006( mesh2d, topography%topo )
      end select
 
      call prof_rapend  ('_MkTOPO_main', 3)
      log_progress(*) 'end making topography data'
 
      output = .true.
    end if
 
    return
  end subroutine mktopo
 
  !-----------------------------------------------------------------------------
!OCL SERIAL
  subroutine mktopo_write( model_mesh, topography )
 
    use scale_time, only: &
      nowdate   => time_nowdate,   &
      nowsubsec => time_nowsubsec, &
      nowdaysec => time_nowdaysec
    use scale_prc, only: prc_myrank
 
    use scale_file_base_meshfield, only: file_base_meshfield
    use scale_mesh_rectdom2d, only: meshrectdom2d
    use scale_mesh_cubedspheredom2d, only: meshcubedspheredom2d
    use scale_mesh_base2d, only: &
      mftype2d_xy => meshbase2d_dimtypeid_xy
 
    implicit none
    class(atmosmesh), target, intent(in) :: model_mesh
    class(meshtopography), intent(inout) :: topography
 
    type(file_base_meshfield) :: file
    class(meshbase2d), pointer :: mesh
 
    logical :: file_existed
    integer, parameter :: vid_topo = 1
    !--------------------------------------------------
   
    nullify( mesh )
    call model_mesh%ptr_mesh%GetMesh2D( mesh )
    select type( mesh )
    class is (meshcubedspheredom2d)
      call file%Init( 1, meshcubedsphere2d=mesh )
    class is (meshrectdom2d)      
      call file%Init( 1, mesh2d=mesh )
    end select
       
    call file%Create( out_basename, out_title, out_dtype, &
                      file_existed,                       &
                      myrank=prc_myrank                   )
 
    if ( .not. file_existed ) then
      call file%Put_GlobalAttribute_time( nowdate, nowsubsec )
    end if
 
    call file%Def_Var( topography%topo, "TOPOGRAPHY", vid_topo, mftype2d_xy, 'XY' )
    call file%End_def()
    call file%Write_var2D( vid_topo, topography%topo, nowdaysec, nowdaysec )
    call file%Close()
    call file%Final()
 
    return
  end subroutine mktopo_write
 
  !-- private---------------------------------------------------------------------
 
  !-----------------------------------------------------------------------------
!OCL SERIAL  
  subroutine mktopo_input_file( mesh, topo )
    use scale_file_base_meshfield, only: file_base_meshfield
    use scale_mesh_rectdom2d, only: meshrectdom2d
    use scale_mesh_cubedspheredom2d, only: meshcubedspheredom2d
    use scale_mesh_base2d, only: &
      mftype2d_xy => meshbase2d_dimtypeid_xy
 
    implicit none
 
    class(meshbase2d), intent(in), target :: mesh
    class(meshfield2d), intent(inout) :: topo
 
    character(len=H_LONG) :: in_basename
    character(len=H_MID) :: varname
 
    namelist / param_mktopo_input_file / &
      in_basename, &
      varname
 
    integer :: ierr    
    integer :: n
    integer :: ke2d
    type(localmesh2d), pointer :: lmesh2d
 
    type(file_base_meshfield) :: file
 
    logical :: file_existed
    !--------------------------------
 
    log_info("MKTOPO_input_file",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_mktopo_input_file,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("MKTOPO_input_file",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("MKTOPO_input_file",*) 'Not appropriate names in namelist PARAM_MKTOPO_INPUT_FILE. Check!'
       call prc_abort
    endif
    log_nml(param_mktopo_input_file)
 
    !-- Read topography data
 
    select type( mesh )
    class is (meshcubedspheredom2d)
      call file%Init( 1, meshcubedsphere2d=mesh )
    class is (meshrectdom2d)      
      call file%Init( 1, mesh2d=mesh )
    end select
 
    call file%Open( in_basename, myrank=prc_myrank)
    call file%Read_Var( mftype2d_xy, varname, topo )
 
    call file%Close()
    call file%Final()
 
    return
  end subroutine mktopo_input_file
 
 
  !-----------------------------------------------------------------------------
!OCL SERIAL  
  subroutine mktopo_flat( mesh, topo )
    implicit none
 
    class(meshbase2d), intent(in), target :: mesh
    class(meshfield2d), intent(inout) :: topo
 
    ! flat mountain parameter
    real(rp) :: flat_height   =  100.0_rp 
 
    namelist / param_mktopo_flat / &
       flat_height
 
    integer :: ierr    
    integer :: n
    integer :: ke2d
    type(localmesh2d), pointer :: lmesh2d
    !--------------------------------
 
    log_info("MKTOPO_flat",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_mktopo_flat,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("MKTOPO_flat",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("MKTOPO_flat",*) 'Not appropriate names in namelist PARAM_MKTOPO_FLAT. Check!'
       call prc_abort
    endif
    log_nml(param_mktopo_flat)
 
    do n=1, mesh%LOCAL_MESH_NUM
      lmesh2d => mesh%lcmesh_list(n)
      !$omp parallel do
      do ke2d=lmesh2d%NeS, lmesh2d%NeE
        topo%local(n)%val(:,ke2d) = flat_height
      end do
    end do
    
    return
  end subroutine mktopo_flat
 
 
  !-----------------------------------------------------------------------------
!OCL SERIAL
  subroutine mktopo_bellshape( mesh, topo )
    implicit none
 
    class(meshbase2d), intent(in), target :: mesh
    class(meshfield2d), intent(inout) :: topo
 
    ! bell-shaped mountain parameter
    real(rp) :: bell_cx     =   0.0e0_rp 
    real(rp) :: bell_cy     =   0.0e3_rp 
    real(rp) :: bell_r      =   2.e3_rp  
    real(rp) :: bell_height =  100.0_rp  
    logical  :: bell_quasi_2d = .false. 
    namelist / param_mktopo_bellshape / &
      bell_cx,     &
      bell_cy,     &
      bell_r,      &    
      bell_height, &
      bell_quasi_2d
 
    integer :: ierr    
    integer :: n
    integer :: ke2d
    type(localmesh2d), pointer :: lmesh2d
    class(elementbase2d), pointer :: elem
 
    real(rp), allocatable :: r2(:)
    real(rp) :: fac_y_quasi2d
    !--------------------------------
 
    log_info("MKTOPO_bellshape",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_mktopo_bellshape,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("MKTOPO_bellshape",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("MKTOPO_bellshape",*) 'Not appropriate names in namelist PARAM_MKTOPO_BELLSHAPE. Check!'
       call prc_abort
    endif
    log_nml(param_mktopo_bellshape)
 
    if ( bell_quasi_2d ) then
      fac_y_quasi2d = 0.0_rp
    else
      fac_y_quasi2d = 1.0_rp
    end if
 
    do n=1, mesh%LOCAL_MESH_NUM
      lmesh2d => mesh%lcmesh_list(n)
      elem => lmesh2d%refElem2D
 
      allocate( r2(elem%Np) )
      !$omp parallel do private(r2)
      do ke2d=lmesh2d%NeS, lmesh2d%NeE
        r2(:) = (                   ( lmesh2d%pos_en(:,ke2d,1) - bell_cx )**2   & 
                  + fac_y_quasi2d * ( lmesh2d%pos_en(:,ke2d,2) - bell_cy )**2 ) &
                / bell_r**2
        topo%local(n)%val(:,ke2d) = bell_height / ( 1.0_rp + r2(:) )
      end do
      deallocate( r2 )
    end do
    
    return
  end subroutine mktopo_bellshape
 
  !-----------------------------------------------------------------------------
!OCL SERIAL
  subroutine mktopo_schaer_type_mountain( mesh, topo )
    implicit none
 
    class(meshbase2d), intent(in), target :: mesh
    class(meshfield2d), intent(inout) :: topo
 
    ! Schaer-type mountain parameter
    real(rp) :: schaer_cx       =  25.e3_rp 
    real(rp) :: schaer_rx       =   5.e3_rp 
    real(rp) :: schaer_lambda   =   4.e3_rp 
    real(rp) :: schaer_height   =  250.0_rp 
    namelist / param_mktopo_schaer / &
       schaer_cx,     &
       schaer_rx,     &
       schaer_lambda, &
       schaer_height
 
    integer :: ierr    
    integer :: n
    integer :: ke2d
    type(localmesh2d), pointer :: lmesh2d
    class(elementbase2d), pointer :: elem
 
    real(rp), allocatable :: dist(:)
    real(rp) :: fac_y_quasi2d
    !--------------------------------
 
    log_info("MKTOPO_Schaer",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_mktopo_schaer,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("MKTOPO_Schaer",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("MKTOPO_Schaer",*) 'Not appropriate names in namelist PARAM_MKTOPO_SCAHER. Check!'
       call prc_abort
    endif
    log_nml(param_mktopo_schaer)
 
    do n=1, mesh%LOCAL_MESH_NUM
      lmesh2d => mesh%lcmesh_list(n)
      elem => lmesh2d%refElem2D
 
      allocate( dist(elem%Np) )
      !$omp parallel do private(dist)
      do ke2d=lmesh2d%NeS, lmesh2d%NeE
        dist(:) = exp( - ( lmesh2d%pos_en(:,ke2d,1) - schaer_cx )**2 / schaer_rx**2 )
        topo%local(n)%val(:,ke2d) = schaer_height * dist(:) * ( cos( pi * ( lmesh2d%pos_en(:,ke2d,1) - schaer_cx ) / schaer_lambda ) )**2
      end do
      deallocate( dist )
    end do
    
    return
  end subroutine mktopo_schaer_type_mountain
 
  !-----------------------------------------------------------------------------
  subroutine mktopo_bellshape_global( mesh, topo )
    implicit none
 
    class(meshbase2d), intent(in), target :: mesh
    class(meshfield2d), intent(inout) :: topo
 
    ! bell-shaped mountain parameter
    real(rp) :: bell_clon   =   0.0e0_rp 
    real(rp) :: bell_clat   =   0.0e0_rp 
    real(rp) :: bell_r      =   2.e3_rp  
    real(rp) :: bell_height =  100.0_rp  
    namelist / param_mktopo_bellshape_global / &
      bell_clon,     &
      bell_clat,     &
      bell_r,        &    
      bell_height
 
    integer :: ierr    
    integer :: n
    integer :: ke2d
    type(localmesh2d), pointer :: lmesh2d
    class(elementbase2d), pointer :: elem
 
    real(rp), allocatable :: r(:)
    !--------------------------------
 
    log_info("MKTOPO_bellshape_global",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_mktopo_bellshape_global,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("MKTOPO_bellshape_global",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("MKTOPO_bellshape_global",*) 'Not appropriate names in namelist PARAM_MKTOPO_BELLSHAPE_GLOBAL. Check!'
       call prc_abort
    endif
    log_nml(param_mktopo_bellshape_global)
 
    do n=1, mesh%LOCAL_MESH_NUM
      lmesh2d => mesh%lcmesh_list(n)
      elem => lmesh2d%refElem2D
 
      allocate( r(elem%Np) )
      !$omp parallel do private(r)
      do ke2d=lmesh2d%NeS, lmesh2d%NeE
        r(:) = rplanet / bell_r &
             * acos( sin(bell_clat) * sin(lmesh2d%lat(:,ke2d))                                        &
                   + cos(bell_clat) * cos(lmesh2d%lat(:,ke2d)) * cos(lmesh2d%lon(:,ke2d) - bell_clon) )
        topo%local(n)%val(:,ke2d) = bell_height / ( 1.0_rp + r(:)**2 )
      end do
      deallocate( r )
    end do
    
    return
  end subroutine mktopo_bellshape_global
 
  !-----------------------------------------------------------------------------
  subroutine mktopo_schaer_type_global( mesh, topo )
    implicit none
 
    class(meshbase2d), intent(in), target :: mesh
    class(meshfield2d), intent(inout) :: topo
 
    ! bell-shaped mountain parameter
    real(rp) :: schaer_clon
    real(rp) :: schaer_clat
    real(rp) :: schaer_r
    real(rp) :: schaer_lambda
    integer  :: schaer_shape_id
    real(rp) :: schaer_height
    logical :: quasi_2d_flag
 
    namelist / param_mktopo_schaer_global / &
      schaer_clon,     &
      schaer_clat,     &
      schaer_r,        &
      schaer_lambda,   &
      schaer_shape_id, &
      schaer_height,   &
      quasi_2d_flag
 
    integer :: ierr    
    integer :: n
    integer :: ke2d
    type(localmesh2d), pointer :: lmesh2d
    class(elementbase2d), pointer :: elem
 
    real(rp), allocatable :: r(:)
    real(rp), allocatable :: mwt_shape(:)
 
    !--------------------------------
 
    log_info("MKTOPO_Schaer_global",*) 'Setup'
 
    schaer_clon     = 1.0_rp / 4.0_rp * pi
    schaer_clat     = 0.0_rp
    schaer_r        = rplanet * 3.0_rp / 4.0_rp * pi
    schaer_lambda   = rplanet * pi / 16.0_rp
    schaer_shape_id = 1
    schaer_height   = 2000.0_rp
    quasi_2d_flag   = .false.
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_mktopo_schaer_global,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("MKTOPO_Schaer_global",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("MKTOPO_Schaer_global",*) 'Not appropriate names in namelist PARAM_MKTOPO_SCHAER_GLOBAL. Check!'
       call prc_abort
    endif
    log_nml(param_mktopo_schaer_global)
 
    do n=1, mesh%LOCAL_MESH_NUM
      lmesh2d => mesh%lcmesh_list(n)
      elem => lmesh2d%refElem2D
 
      allocate( r(elem%Np), mwt_shape(elem%Np) )
      !$omp parallel do private(r, mwt_shape)
      do ke2d=lmesh2d%NeS, lmesh2d%NeE
        if ( quasi_2d_flag ) then
!          r(:) = RPlanet * ( min( abs(lmesh2D%lon(:,ke2d) - SCHAER_Clon), abs(lmesh2D%lon(:,ke2d) - (SCHAER_Clon + 2.0_RP * PI ) ) ) )
          r(:) = rplanet * abs(lmesh2d%lon(:,ke2d) - schaer_clon)
        else
          r(:) = rplanet &
              * acos( sin(schaer_clat) * sin(lmesh2d%lat(:,ke2d))                                          &
                    + cos(schaer_clat) * cos(lmesh2d%lat(:,ke2d)) * cos(lmesh2d%lon(:,ke2d) - schaer_clon) )
        end if
 
        if ( schaer_shape_id == 1 ) then
          mwt_shape(:) = exp( - ( r(:) / schaer_r )**2 ) 
        else if ( schaer_shape_id == 2 ) then
          where ( r(:) < schaer_r )
            mwt_shape(:) = 0.5_rp * ( 1.0_rp + cos( pi * r(:) / schaer_r ) )
          elsewhere
            mwt_shape(:) = 0.0_rp
          end where          
        end if
 
        if ( quasi_2d_flag ) then
          mwt_shape(:) = mwt_shape(:) * cos(lmesh2d%lat(:,ke2d))
        end if
 
        topo%local(n)%val(:,ke2d) = schaer_height *  mwt_shape(:) * cos( pi * r(:) / schaer_lambda )**2
      end do
      deallocate( r, mwt_shape )
    end do
    
    return
  end subroutine mktopo_schaer_type_global
 
  !-----------------------------------------------------------------------------
!OCL SERIAL
  subroutine mktopo_barocwave_global_jw2006( mesh, topo )
    use mod_mktopo_util, only: &
      calc_topo => mktopoutil_barocwave_global_jw2006_calc_topo
    implicit none
 
    class(meshbase2d), intent(in), target :: mesh
    class(meshfield2d), intent(inout) :: topo
 
    ! parameters of baroclinic wave test case in JW2006
    real(rp) :: eta0 = 0.252_rp  
    real(rp) :: u0   = 35.e0_rp  
 
    namelist / param_mktopo_barocwave_global_jw2006 / &
      eta0, u0
    
    integer :: ierr    
    integer :: n
    integer :: ke2d
    type(localmesh2d), pointer :: lmesh2d
    class(elementbase2d), pointer :: elem
    !--------------------------------
 
    log_info("MKTOPO_barocwave_JW2006",*) 'Setup'
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf, nml=param_mktopo_barocwave_global_jw2006, iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("MKTOPO_barocwave_JW2006",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
       log_error("MKTOPO_barocwave_JW2006",*) 'Not appropriate names in namelist PARAM_MKTOPO_BAROCWAVE_GLOBAL_JW2006. Check!'
       call prc_abort
    endif
    log_nml(param_mktopo_barocwave_global_jw2006)
 
    do n=1, mesh%LOCAL_MESH_NUM
      lmesh2d => mesh%lcmesh_list(n)
      elem => lmesh2d%refElem2D
      
      !$omp parallel do
      do ke2d=lmesh2d%NeS, lmesh2d%NeE
        call calc_topo( topo%local(n)%val(:,ke2d), & ! (out)
          u0, eta0, lmesh2d%lat(:,ke2d), elem%Np )   ! (in)
      end do
    end do
    
    return
  end subroutine mktopo_barocwave_global_jw2006
 
end module mod_mktopo