scale_mesh_bndinfo.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module scale_mesh_bndinfo
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
 
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
 
  type, public :: meshbndinfo
    integer, allocatable :: list(:)
    real(rp), allocatable :: val(:)
    character(len=H_SHORT) :: tag
  contains
    procedure :: init => meshbndinfo_init
    procedure :: final => meshbndinfo_final
    procedure, private :: set_by_id => meshbndinfo_set_by_id
    procedure, private :: set_by_name => meshbndinfo_set_by_name
    generic :: set => set_by_id, set_by_name
  end type meshbndinfo
  
  public :: bndtype_nametoid
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  character(len=*), public , parameter :: bnd_type_nospec_name  = 'NONSPEC'
  integer, public, parameter :: bnd_type_nospec_id              = 0
  character(len=*), public, parameter :: bnd_type_periodic_name = 'PERIODIC'
  integer, public, parameter  :: bnd_type_periodic_id           = 1
  character(len=*), public, parameter  :: bnd_type_slip_name    = 'SLIP'
  integer, public, parameter :: bnd_type_slip_id                = 2
  character(len=*), public, parameter  :: bnd_type_noslip_name  = 'NOSLIP'
  integer, public, parameter:: bnd_type_noslip_id               = 3
  character(len=*), public , parameter :: bnd_type_adiabat_name = 'ADIABATIC'
  integer, public, parameter :: bnd_type_adiabat_id             = 4
  character(len=*), public , parameter :: bnd_type_fixval_name  = 'FIXVAL'
  integer, public, parameter :: bnd_type_fixval_id              = 5
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures
  !
  !-------------------
 
contains
!OCL SERIAL
  subroutine meshbndinfo_init(this, list_size, tag)
    use scale_const, only: &
      undef8 => const_undef8
    implicit none
    class(meshbndinfo), intent(inout) :: this
    integer, intent(in) :: list_size
    character(*), optional, intent(in) :: tag
 
    integer :: i
    !------------------------------------------------------
 
    allocate( this%list(list_size) )
    allocate( this%val(list_size) )
 
    !$omp parallel do
    do i = 1, list_size
      this%list(i) = bnd_type_nospec_id
      this%val(i)  = undef8
    end do
 
    if (present(tag)) then
      this%tag = tag
    else
      this%tag = ''
    end if
    
    return
  end subroutine meshbndinfo_init
 
!OCL SERIAL
  subroutine meshbndinfo_final(this)
    implicit none
    class(meshbndinfo), intent(inout) :: this
    !------------------------------------------------------
 
    if (allocated(this%list)) deallocate(this%list)
    if (allocated(this%val)) deallocate(this%val)
    
    return
  end subroutine meshbndinfo_final  
 
!OCL SERIAL
  subroutine meshbndinfo_set_by_id(this, is, ie, bnd_type_id, val)
    implicit none
    class(meshbndinfo), intent(inout) :: this
    integer, intent(in) :: is
    integer, intent(in) :: ie
    integer, intent(in) :: bnd_type_id
    real(rp), intent(in), optional :: val
    !------------------------------------------------------
 
    this%list(is:ie) = bnd_type_id
    if ( present(val) ) then
      this%val(is:ie) = val
    end if
 
    return
  end subroutine meshbndinfo_set_by_id
 
!OCL SERIAL
  subroutine meshbndinfo_set_by_name(this, is, ie, bnd_type_name, val)
    implicit none
    class(meshbndinfo), intent(inout) :: this
    integer, intent(in) :: is
    integer, intent(in) :: ie
    character(*), intent(in) :: bnd_type_name
    real(rp), intent(in), optional :: val
 
    integer :: bnd_type_id
    !------------------------------------------------------
    bnd_type_id = bndtype_nametoid(bnd_type_name)
    call meshbndinfo_set_by_id(this, is, ie, bnd_type_id, val)
 
    return
  end subroutine meshbndinfo_set_by_name
 
!OCL SERIAL
  function bndtype_nametoid(bnd_type_name) result(bnd_type_id)
    implicit none
    character(*), intent(in) :: bnd_type_name
 
    integer :: bnd_type_id
    !------------------------------------------------------
 
    select case(trim(bnd_type_name))
    case (bnd_type_nospec_name)
      bnd_type_id = bnd_type_nospec_id
    case (bnd_type_periodic_name)
      bnd_type_id = bnd_type_periodic_id
    case (bnd_type_slip_name)
      bnd_type_id = bnd_type_slip_id
    case (bnd_type_noslip_name)
      bnd_type_id = bnd_type_noslip_id
    case (bnd_type_adiabat_name)
      bnd_type_id = bnd_type_adiabat_id
    case (bnd_type_fixval_name)
      bnd_type_id = bnd_type_fixval_id      
    case default
      log_error('BndType_NameToID ',*) trim(bnd_type_name) // ' is not supported. Check!'
      call prc_abort
    end select
 
    return
  end function bndtype_nametoid 
 
end module scale_mesh_bndinfo