scale_meshfieldcomm_rectdom2d.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module scale_meshfieldcomm_rectdom2d
 
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
 
  use scale_element_base, only: &
    elementbase, elementbase2d
  use scale_mesh_rectdom2d, only: meshrectdom2d
  use scale_meshfield_base, only: meshfield2d
  use scale_meshfieldcomm_base, only: &
    meshfieldcommbase,                               &
    meshfieldcommbase_init, meshfieldcommbase_final, &
    meshfieldcommbase_extract_bounddata,             &
    meshfieldcommbase_set_bounddata,                 &
    meshfieldcontainer
  use scale_localmesh_2d, only: localmesh2d
   
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedure
  ! 
 
  type, public, extends(meshfieldcommbase) :: meshfieldcommrectdom2d
    class(meshrectdom2d), pointer :: mesh2d
  contains
    procedure, public :: init => meshfieldcommrectdom2d_init
    procedure, public :: put => meshfieldcommrectdom2d_put
    procedure, public :: get => meshfieldcommrectdom2d_get
    procedure, public :: exchange => meshfieldcommrectdom2d_exchange  
    procedure, public :: final => meshfieldcommrectdom2d_final
  end type meshfieldcommrectdom2d
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: push_localsendbuf
  
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer :: bufsize_per_field
  integer, parameter :: comm_face_num = 4
 
contains
  subroutine meshfieldcommrectdom2d_init( this, &
    sfield_num, hvfield_num, htensorfield_num, mesh2d )
    implicit none
    
    class(meshfieldcommrectdom2d), intent(inout) :: this
    integer, intent(in) :: sfield_num
    integer, intent(in) :: hvfield_num
    integer, intent(in) :: htensorfield_num
    class(meshrectdom2d), intent(in), target :: mesh2d
    
    type(localmesh2d), pointer :: lcmesh
    integer :: n
    integer :: nnode_lcmeshface(comm_face_num,mesh2d%local_mesh_num)
    !-----------------------------------------------------------------------------
    
    this%mesh2d => mesh2d
    lcmesh => mesh2d%lcmesh_list(1)
    bufsize_per_field = 2*(lcmesh%NeX + lcmesh%NeY)*lcmesh%refElem2D%Nfp
 
    do n=1, this%mesh2d%LOCAL_MESH_NUM
      lcmesh => this%mesh2d%lcmesh_list(n)
      nnode_lcmeshface(:,n) = (/ lcmesh%NeX, lcmesh%NeY, lcmesh%NeX, lcmesh%NeY /) * lcmesh%refElem2D%Nfp
    end do
 
    call meshfieldcommbase_init( this, sfield_num, hvfield_num, htensorfield_num, bufsize_per_field, comm_face_num, nnode_lcmeshface, mesh2d)  
  
    return
  end subroutine meshfieldcommrectdom2d_init
 
  subroutine meshfieldcommrectdom2d_final( this )
    implicit none
    
    class(meshfieldcommrectdom2d), intent(inout) :: this
    !-----------------------------------------------------------------------------
 
    call meshfieldcommbase_final( this )
 
    return
  end subroutine meshfieldcommrectdom2d_final
 
  subroutine meshfieldcommrectdom2d_put(this, field_list, varid_s)
    implicit none
    class(meshfieldcommrectdom2d), intent(inout) :: this
    type(meshfieldcontainer), intent(in) :: field_list(:)
    integer, intent(in) :: varid_s
  
    integer :: i
    integer :: n
    type(localmesh2d), pointer :: lcmesh
    !-----------------------------------------------------------------------------
 
    do i=1, size(field_list)
    do n=1, this%mesh%LOCAL_MESH_NUM
      lcmesh => this%mesh2d%lcmesh_list(n)
      call meshfieldcommbase_extract_bounddata( field_list(i)%field2d%local(n)%val, lcmesh%refElem, lcmesh, & ! (in)
        this%send_buf(:,varid_s+i-1,n) )                                                                  ! (out)
    end do
    end do
 
    return
  end subroutine meshfieldcommrectdom2d_put
 
  subroutine meshfieldcommrectdom2d_get(this, field_list, varid_s)
    use scale_meshfieldcomm_base, only: &
      meshfieldcommbase_wait_core
    implicit none
    
    class(meshfieldcommrectdom2d), intent(inout) :: this
    type(meshfieldcontainer), intent(inout) :: field_list(:)
    integer, intent(in) :: varid_s
 
    integer :: i
    integer :: n
    type(localmesh2d), pointer :: lcmesh
    !-----------------------------------------------------------------------------
 
    !--
    if ( this%call_wait_flag_sub_get ) &
      call meshfieldcommbase_wait_core( this, this%commdata_list )
 
    do i=1, size(field_list) 
    do n=1, this%mesh2d%LOCAL_MESH_NUM
      lcmesh => this%mesh2d%lcmesh_list(n)
      call meshfieldcommbase_set_bounddata( this%recv_buf(:,varid_s+i-1,n), lcmesh%refElem, lcmesh, & !(in)
         field_list(i)%field2d%local(n)%val )                                                         !(out)
    end do
    end do
 
    return
  end subroutine meshfieldcommrectdom2d_get
 
!OCL SERIAL
  subroutine meshfieldcommrectdom2d_exchange( this, do_wait )
    use scale_meshfieldcomm_base, only: &
      meshfieldcommbase_exchange_core,  &
      localmeshcommdata
 
    implicit none
  
    class(meshfieldcommrectdom2d), intent(inout), target :: this
    logical, intent(in), optional :: do_wait
 
    integer :: n, f
    type(localmeshcommdata), pointer :: commdata
    !-----------------------------------------------------------------------------
 
    do n=1, this%mesh%LOCAL_MESH_NUM
    do f=1, this%nfaces_comm
      commdata => this%commdata_list(f,n)
      call push_localsendbuf( commdata%send_buf(:,:),             &  ! (inout)
        this%send_buf(:,:,n), commdata%s_faceID, this%is_f(f,n),  &  ! (in)
        commdata%Nnode_LCMeshFace, this%field_num_tot)               ! (in)
    end do
    end do
 
    !-----------------------
 
    call meshfieldcommbase_exchange_core( this, this%commdata_list(:,:), do_wait )
 
    !---------------------
 
    return
  end subroutine meshfieldcommrectdom2d_exchange
 
!----------------------------
 
!OCL SERIAL
  subroutine push_localsendbuf( lc_send_buf, send_buf, s_faceID, is, Nnode_LCMeshFace, var_num )
    implicit none
 
    integer, intent(in) :: var_num
    integer, intent(in) ::  nnode_lcmeshface
    real(rp), intent(inout) :: lc_send_buf(nnode_lcmeshface,var_num)
    real(rp), intent(in) :: send_buf(bufsize_per_field,var_num)  
    integer, intent(in) :: s_faceid, is
  
    integer :: ie
    !-----------------------------------------------------------------------------
 
    ie = is + nnode_lcmeshface - 1
    if ( s_faceid > 0 ) then
      lc_send_buf(:,:) = send_buf(is:ie,:)   
    else
      lc_send_buf(:,:) = send_buf(ie:is:-1,:)   
    end if 
    
    return
  end subroutine push_localsendbuf
 
end module scale_meshfieldcomm_rectdom2d